# Kapitel 7_b:
# Schwingungsversuch an einer Probe aus viskoelastischem Material
# (Kelvin-Modell)
#  2015  Friedrich U. Mathiak, 
# mathiak@mechanik-info.de
# 
> restart: with(plots):
#  Es soll ein Schwingungsversuch an einer Probe aus viskoelastischem Material durchgefhrt werden. Zur mathematischen Beschreibung des Versuchs verwenden wir das Kelvin-Modell und belasten die spannungsfreie Probe zurzeit t = 0 mit der harmonischen Kraft F(t) = A cost, (A: Amplitude; : Erregerkreisfrequenz).
# Das Beispiel orientiert sich an meinem  Buchtitel:
# F. U. Mathiak: Technische Mechanik 3, Kinematik und Kinetik  mit Maple- und MapleSim-Anwendungen, Verlag Walter de Gruyter, 2015
# 
# Ein Kelvin-Modell (s.h. obige Abbildung) besteht aus der Parallelschaltung von Feder und Dmpfer. Ist l0 die Elementlnge zum Zeitpunkt t = t0, dann lautet die zugehrige Differenzialgleichung:
> ode1:=diff(l(t),t)+k/c*l(t)-1/c*(F(t)+k*l0);
# Wir fhren noch dl(t) = l(t) - l0 ein, also
> l(t):=dl(t) + l0;
# Dann ist
> ode1;
# Die uere Belastung sei harmonisch (A: Amplitude, : Erregerkraftfrequenz)
> F(t):=A*cos(Omega*t);
# Zum Zeitpunkt t = t0 sei das Element entspannt.  Damit lautet die Anfangsbedingung
> AB:=dl(t0)=0;
# Das fhrt auf folgende Lsung fr die Lngennderung dl(t)
> loe:=dsolve({ode1,AB},dl(t)); assign(%);
# Ist die Feder zum Zeitpunkt t = t0 = 0 entspannt, also
> t0:=0;
# dann verbleibt
> dl:=unapply(simplify(rhs(loe)),t);
# Fr den weiteren Rechengang whlen wir folgende Systemwerte
> A:=1; Omega:=1; k:=1; c:=1/5;
# Das fhrt auf die Lngennderung des Kelvin-Modells
> dl(t);
# Damit ergeben sich folgende Krfte in Feder und Dmpfer
> FF:=unapply(k*dl(t),t);     #Federkraft
;
> FD:=unapply(c*D(dl)(t),t);  #Dmpferkraft
;
# 
> FM:=unapply(FF(t)+FD(t),t);
> tE:=20.;
# Wir stellen die Ergebnisse grafisch dar. Zunchst werden die Krfte im Kelvin-Modell als Funktion der Zeit t geplottet. 
> plot([FF(t),FD(t),F(t)],t=0..tE,title ="\nKrfte im Kelvin-Modell\n",titlefont=["ROMAN",15],legend =["Feder","Dmpfer","Gesamt"],legendstyle=[font = ["HELVETICA", 9],location=bottom],color=[blue,red,black],labels = ["Zeit t","Krfte"],gridlines=true,axes=boxed);
# In einem zweiten Schritt erfolgt die Ausgabe der Krfte als Funktion den Elementlngennderung dl.
> tae:=t=0..2.*Pi/Omega;
> plot([[dl(t),FF(t),tae],[dl(t),FD(t),tae],[dl(t),F(t),tae]],title ="\nKrfte im Kelvin-Modell\n", titlefont = ["ARIAL", 15], legend = ["F", "Dmpfer","Gesamt"], legendstyle = [font = ["HELVETICA", 9], location = bottom],axes = boxed,scaling = constrained,gridlines=true, color=[blue, red, black],labels = ["Verschiebung Gesamtmodell","Krfte"]);
# Hinweis: Nach hinreichend groer Zeit verschwindet die Anfangsstrung  in den Lsungen und die anfangs offenen Ellipsen sind dann nherungsweise geschlossen:
> tae:=t=10*Pi/Omega..12*Pi/Omega;
> plot([[dl(t),FF(t),tae],[dl(t),FD(t),tae],[dl(t),F(t),tae]],title ="\nKrfte im Kelvin-Modell\n", titlefont = ["ARIAL", 15], legend = ["F", "Dmpfer","Gesamt"], legendstyle = [font = ["HELVETICA", 9], location = bottom],axes = boxed,scaling = constrained,gridlines=true, color=[blue, red, black],labels = ["Verschiebung Gesamtmodell","Krfte"]);
# Abschlieend untersuchen wir noch den Kriechversuch am Kelvin-Element. Dazu belasten wir auf das Kelvin-Modell zum Zeitpunkt t = t0 mit einer konstante Kraft F = F0, die zum Zeitpunkt t = t1 wieder entfernt wird. 
# 
> restart:
> F(t):=piecewise(t < t1 and t > t0,F0,0);
> ode1:=diff(l(t),t)+k/c*l(t)-1/c*(F(t)+k*l0);
> l(t):=dl(t) + l0;
> ode1;
# Wir whlen folgende Systemwerte
> F0:=0.5; k:=0.5; c:=2; t0:=5; t1:=40; tE:= 80;
# Die Anfangsbedingung lautet
> AB:=dl(t0)=0;
# Damit ergibt sich folgende Lsung
> loe:=dsolve({ode1,AB},dl(t)): dl:=unapply(rhs(loe),t);
# Wir geben die Element-Lngennderung als Funtion der Zeit aus:
> plot(dl,0..tE,gridlines,title = "\nKriechversuch am Kelvin-Modell\n",titlefont = ["ARIAL", 15],labels = ["Zeit t", "Lngennderung dl"], labeldirections = ["horizontal", "vertical"],axes=boxed,filled = [color = "Blue", transparency = .5]);
# Beim Kelvin-Modell tritt nach der Entlastung keine bleibende Verformung auf. Das Modell verhlt sich unmittelbar nach Lastaufbringung viskos, langfristig dagegen elastisch. Dieser Effekt wird verzgerte Elastizitt, elastische Nachwirkung oder auch Anelastizitt genannt. Wird die Last entfernt, dann tritt Rckkriechen (Kriecherholung) des Modells auf die Lnge l0 auf (dl = 0) auf. Wird die Lnge l konstant gehalten, dann resultiert daraus eine Kraft F = k dl.
>  
;
> 
;
