# Kapitel _03_d: Welle mit Rotor, Unwuchtwirkung 
#  2015  Friedrich U. Mathiak, 
# mathiak@mechanik-info.de
# 
> restart: with(LinearAlgebra): 
# Beispiel 3-8:
# 
# 
# 
# Die obige Abbildung zeigt eine beidseitig momentenfrei gelagerte Welle, die einen Rotor der Masse m trgt, der mit konstanter Winkelgeschwindigkeit um die Wellenachse umluft. Zu beachten ist, dass die Wellenachse nicht durch den Schwerpunkt S des Rotors verluft. Das Eigengewicht von Rotor und Welle kann vernachlssigt werden. Zur Beschreibung dieser ebenen Bewegung des als starr angenommenen Krpers fhren wir krperfeste Koordinaten ein. Jedes Massenelement dm des Rotors fhrt dabei eine ebene Kreisbewegung in der (1,2)-Ebene aus. Als Ursprung des Koordinatensystems wird der raumfeste Punkt 0 am Lager A gewhlt. Die Auflagerkrfte A(1) und B(1) werden im mitbewegten krperfesten Koordinatensystem dargestellt. Gesucht werden die kinetischen Drcke an den Lagern A und B. 
# Wir berechnen in einem ersten Schritt die Massentrgheitsmomente des Rotors (Dicke h, Radius a,  = h/a, Masse m)  bezglich des Punktes A in krperfesten Koordinaten. 
# Die Eigentrgheitsmomente des Rotors sind:
> Theta1:=1/12*m*a^2*(3+4*eta^2); Theta2:=Theta1; Theta3:=1/2*m*a^2;
> ThetaS:=Matrix(1..3,1..3, Vector([Theta1,Theta2,Theta3]),shape=diagonal);  #Eigentrgheitsmomente des Rotors
;
> rSp:=Vector([x1S,x2S,0]): rS:=rSp + Vector([0,0,c]): EM:=Matrix(3,shape = identity):
# Damit folgen nach dem Satz von Steiner fr parallele Achsen (Buch TM3) die Trgheitsmomente des Rotors bezogen auf den Punkt A
> ThetaA:=ThetaS + m*(Transpose(rS).rS*EM - rS.Transpose(rS));
# Wir notieren den Vektor der Winkelgeschwindigkeit fr eine reine Drehung um die 3-Achse
> om:=Vector([0,0,omega(t)]);
# Fr den Drallvektor in krperfesten Koordinaten bezogen auf den Punkt A  gilt dann
> L:=ThetaA.om; 
# Die zeitliche nderung des  Drallvektors in krperfesten Koordinaten bezogen auf den Punkt A  errechnen wir  zu
> Lp:=map(diff,L,t) + CrossProduct(om,L);
# Wir konkretisieren unsere Aufgabe und betrachten 
> omega(t):= omega0;
# eine reine Drehung um die 3-Achse mit konstanter Winkelgeschwindigkeit. Damit verbleiben
> L; Lp;
# Zur Berechnung der Lagerkrfte A und B muss der starre Krper freigeschnitten werden. Anschlieend notieren wir den Drallsatz bezogen auf den Punkt A.  Dazu bentigen wir das  Moment der ueren Krfte bezogen auf denselben Punkt. Da wir das Eigengewicht der Welle und des Rotors vernachlssigen, verbleiben  lediglich die Lagerkrfte A und B als resultierende uere Krfte. Wir berechnen zuerst das Moment der Lagerkraft B bezogen auf den Punkt A:
> rB:=Vector(3,[0,0,l]); LB:=Vector([B[1],B[2],0]);
> MB:=CrossProduct(rB,LB);  #Moment der Lagerkraft B bezogen auf den Punkt A
;
# Wir lsen nach den unbekannten Lagerkraftkomponenten auf
> gl:=seq(MB[i]=Lp[i],i=1..2); solve({gl},{B[1],B[2]}): assign(%);
> LB;  #Lagerkraft B
;
# Die Auflagerkraft A ermitteln wir aus dem Schwerpunktsatz. Dazu wird die Beschleunigung des Schwerpunktes S des Rotors bentigt, die wir dem Kapitel 1.1.4 (Buch TM3) ber die Kreisbewegung entnehmen knnen
> aS:=-om[3]^2*rSp;  #Beschleunigung des Schwerpunktes bei Drehung um die 3-Achse 
;
> LA:=m*aS-LB;  #Lagerkraft A
;
# Die Betrge der Auflagerkrfte wachsen offensichtlich mit dem Quadrat der Winkelgeschwindigkeit.
# Die Lagerkrfte verschwinden immer dann, wenn
# 1.) die Drehachse durch den Krperschwerpunkt S verluft ( rSp = 0), und 
# 2.) die Drehachse mit A[1,3] = A[2,3] = 0  eine Haupttrgheitsachse ist. 
# Hierzu ein Zahlenbeispiel. Der Rotor luft mit einer konstanten Drehzahl von 750 U/min. Damit ist
> omega0:=evalf(2*Pi*750/60*Unit(1/'s'));
> m  :=10*Unit(kilogram[SI]); 
> x1S:=0.025*Unit(meter[SI]); 
> x2S:=0.020*Unit(meter[SI]); 
> c  :=0.4*Unit(meter[SI]);
> l  :=1.0*Unit(meter[SI]);
> a  :=0.2*Unit(meter[SI])
;
> eta:=0.5;
> ThetaA;
> LA:=combine(LA, 'units');
> LB:=combine(LB, 'units');
# Diese Krfte sind zur Lagerberechnung  in umgekehrter Richtung auf die Lager aufzubringen. 
# In einem raumfesten Koordinatensystem sind die umlaufenden Lagerdrcke A(1) und B(1) harmonische Funktionen. Beispielsweise ist A(0) = R3T A(1)  . Ist das das krperfeste Koordinatensystem (1) gegenber dem raumfesten Sysstem (0) mit dem Winkel  um die 3-Achse  gedreht, dann ist mit
> R3T:=Matrix(3,3,[[cos(phi),sin(phi),0],[-sin(phi),cos(phi),0],[0,0,1]]);
# und fr die Lagerkraft im raumfesten System folgt:
> LA0:=R3T.LA;
# Hinweis: Die kritische Drehzahl einer ursprnglich geraden Welle (E: Elastizittsmodul, I: Flchentrgheitsmoment) bei der die Drehachse durch den Schwerpunkt S verluft, errechnet sich nach TM3 zu omegakr  =sqrt((48 EI`11`)/(`m&ell;`^(3))). ;
# Die Welle mit dem Durchmesse d  sei aus Stahl gefertigt. Im Einzelnen sind:
> d:=0.05*Unit(meter[SI]);
> I11:=Pi*d^4/64;
> E:=210*Unit('kN'/'mm'^2);
> omegakr:=evalf(combine(sqrt(48*E*I11/m/l^3),'units'));
> 
;
