# Kapitel _03_d: Welle mit Rotor, Unwuchtwirkung 
# © 2015  Friedrich U. Mathiak, 
# mathiak@mechanik-info.de
# 
> restart: with(LinearAlgebra): 
# Beispiel 3-8:
# 
# 
# 
# Die obige Abbildung zeigt eine beidseitig momentenfrei gelagerte Welle, die einen Rotor der Masse m trägt, der mit konstanter Winkelgeschwindigkeit um die Wellenachse umläuft. Zu beachten ist, dass die Wellenachse nicht durch den Schwerpunkt S des Rotors verläuft. Das Eigengewicht von Rotor und Welle kann vernachlässigt werden. Zur Beschreibung dieser ebenen Bewegung des als starr angenommenen Körpers führen wir körperfeste Koordinaten ein. Jedes Massenelement dm des Rotors führt dabei eine ebene Kreisbewegung in der (1,2)-Ebene aus. Als Ursprung des Koordinatensystems wird der raumfeste Punkt 0 am Lager A gewählt. Die Auflagerkräfte A(1) und B(1) werden im mitbewegten körperfesten Koordinatensystem dargestellt. Gesucht werden die kinetischen Drücke an den Lagern A und B. 
# Wir berechnen in einem ersten Schritt die Massenträgheitsmomente des Rotors (Dicke h, Radius a, · = h/a, Masse m)  bezüglich des Punktes A in körperfesten Koordinaten. 
# Die Eigenträgheitsmomente des Rotors sind:
> Theta1:=1/12*m*a^2*(3+4*eta^2); Theta2:=Theta1; Theta3:=1/2*m*a^2;
> ThetaS:=Matrix(1..3,1..3, Vector([Theta1,Theta2,Theta3]),shape=diagonal);  #Eigenträgheitsmomente des Rotors
;
> rSp:=Vector([x1S,x2S,0]): rS:=rSp + Vector([0,0,c]): EM:=Matrix(3,shape = identity):
# Damit folgen nach dem Satz von Steiner für parallele Achsen (Buch TM3) die Trägheitsmomente des Rotors bezogen auf den Punkt A
> ThetaA:=ThetaS + m*(Transpose(rS).rS*EM - rS.Transpose(rS));
# Wir notieren den Vektor der Winkelgeschwindigkeit für eine reine Drehung um die 3-Achse
> om:=Vector([0,0,omega(t)]);
# Für den Drallvektor in körperfesten Koordinaten bezogen auf den Punkt A  gilt dann
> L:=ThetaA.om; 
# Die zeitliche Änderung des  Drallvektors in körperfesten Koordinaten bezogen auf den Punkt A  errechnen wir  zu
> Lp:=map(diff,L,t) + CrossProduct(om,L);
# Wir konkretisieren unsere Aufgabe und betrachten 
> omega(t):= omega0;
# eine reine Drehung um die 3-Achse mit konstanter Winkelgeschwindigkeit. Damit verbleiben
> L; Lp;
# Zur Berechnung der Lagerkräfte A und B muss der starre Körper freigeschnitten werden. Anschließend notieren wir den Drallsatz bezogen auf den Punkt A.  Dazu benötigen wir das  Moment der äußeren Kräfte bezogen auf denselben Punkt. Da wir das Eigengewicht der Welle und des Rotors vernachlässigen, verbleiben  lediglich die Lagerkräfte A und B als resultierende äußere Kräfte. Wir berechnen zuerst das Moment der Lagerkraft B bezogen auf den Punkt A:
> rB:=Vector(3,[0,0,l]); LB:=Vector([B[1],B[2],0]);
> MB:=CrossProduct(rB,LB);  #Moment der Lagerkraft B bezogen auf den Punkt A
;
# Wir lösen nach den unbekannten Lagerkraftkomponenten auf
> gl:=seq(MB[i]=Lp[i],i=1..2); solve({gl},{B[1],B[2]}): assign(%);
> LB;  #Lagerkraft B
;
# Die Auflagerkraft A ermitteln wir aus dem Schwerpunktsatz. Dazu wird die Beschleunigung des Schwerpunktes S des Rotors benötigt, die wir dem Kapitel 1.1.4 (Buch TM3) über die Kreisbewegung entnehmen können
> aS:=-om[3]^2*rSp;  #Beschleunigung des Schwerpunktes bei Drehung um die 3-Achse 
;
> LA:=m*aS-LB;  #Lagerkraft A
;
# Die Beträge der Auflagerkräfte wachsen offensichtlich mit dem Quadrat der Winkelgeschwindigkeit.
# Die Lagerkräfte verschwinden immer dann, wenn
# 1.) die Drehachse durch den Körperschwerpunkt S verläuft ( rSp = 0), und 
# 2.) die Drehachse mit ˜A[1,3] = ˜A[2,3] = 0  eine Hauptträgheitsachse ist. 
# Hierzu ein Zahlenbeispiel. Der Rotor läuft mit einer konstanten Drehzahl von 750 U/min. Damit ist
> omega0:=evalf(2*Pi*750/60*Unit(1/'s'));
> m  :=10*Unit(kilogram[SI]); 
> x1S:=0.025*Unit(meter[SI]); 
> x2S:=0.020*Unit(meter[SI]); 
> c  :=0.4*Unit(meter[SI]);
> l  :=1.0*Unit(meter[SI]);
> a  :=0.2*Unit(meter[SI])
;
> eta:=0.5;
> ThetaA;
> LA:=combine(LA, 'units');
> LB:=combine(LB, 'units');
# Diese Kräfte sind zur Lagerberechnung  in umgekehrter Richtung auf die Lager aufzubringen. 
# In einem raumfesten Koordinatensystem sind die umlaufenden Lagerdrücke A(1) und B(1) harmonische Funktionen. Beispielsweise ist A(0) = R3T ÅA(1)  . Ist das das körperfeste Koordinatensystem (1) gegenüber dem raumfesten Sysstem (0) mit dem Winkel Õ um die 3-Achse  gedreht, dann ist mit
> R3T:=Matrix(3,3,[[cos(phi),sin(phi),0],[-sin(phi),cos(phi),0],[0,0,1]]);
# und für die Lagerkraft im raumfesten System folgt:
> LA0:=R3T.LA;
# Hinweis: Die kritische Drehzahl einer ursprünglich geraden Welle (E: Elastizitätsmodul, I: Flächenträgheitsmoment) bei der die Drehachse durch den Schwerpunkt S verläuft, errechnet sich nach TM3 zu omegakr  =sqrt((48 EI`11`)/(`m&ell;`^(3))). ;
# Die Welle mit dem Durchmesse d  sei aus Stahl gefertigt. Im Einzelnen sind:
> d:=0.05*Unit(meter[SI]);
> I11:=Pi*d^4/64;
> E:=210*Unit('kN'/'mm'^2);
> omegakr:=evalf(combine(sqrt(48*E*I11/m/l^3),'units'));
> 
;
