# Kapitel 7_a:
# Schwingungsversuch an einer Probe aus viskoelastischem Material
# (Standard-Modell)
# © 2015  Friedrich U. Mathiak, 
# mathiak@mechanik-info.de
# 
> restart: unprotect(gamma):
# Beispiel 7-1:
# 
# Es soll ein Schwingungsversuch an einer Probe aus viskoelastischem Material durchgeführt werden. Zur mathematischen Beschreibung des Versuchs verwenden wir das Standard-Modell und belasten die spannungsfreie Probe zurzeit t = 0 mit der harmonischen Kraft F(t) = A cos©t, (A: Amplitude; ©: Erregerkreisfrequenz). Das Standard-Modell besteht aus einer Parallelschaltung von Hooke- und Maxwell-Modell.
# Das Beispiel orientiert sich an meinem  Buchtitel:
# F. U. Mathiak: Technische Mechanik 3, Kinematik und Kinetik  mit Maple- und MapleSim-Anwendungen, Verlag Walter de Gruyter, 2015
# Auf die Probe wirkt die Kraft
> F:=unapply(A*cos(Omega*t),t);
> Deltal:= unapply(1/k0*(F(t)+(beta1-gamma)*int(exp(-gamma*(t-tau))*F(tau),tau=0..t)),t);
# Zu Beginn der Lastaufbringung (t = 0) reagieren nur die parallel geschalteten Federn mit der Längenänderung (k0 = k + k1)
> Deltal0:=Deltal(0);
# und der Dämpfer wirkt zunächst wie ein starrer Körper. Die Kraft im Hooke-Element ist
> FH:=unapply(simplify(k*Deltal(t)),t);
# und für die Kraft im Maxwell-Element folgt dann
> FM:=unapply(F(t)-FH(t),t);
# Wir sind noch an der Längenänderung des Dämpfers interessiert. Da beide Federn zu Beginn kräftefrei sind, ist ±(t0) = 0. Damit erhalten wir die Längenänderung des Dämpfers im Maxwell-Element zu 
> Deltal_D1:=unapply(1/c1*int(FM(tau),tau=t0..t),t);
# Die Längenänderung der Feder im Maxwell-Element ist 
> Deltal_F1:=unapply(simplify(Deltal(t)-Deltal_D1(t)),t);
# Für die Probe gelten folgende Systemwerte: 
> k:=1/2; k1:=1; c1:=3/4; A:=1; Omega:=1;
# Damit sind
> k0:=k + k1; beta1:=k1/c1; gamma:=beta1*k/k0;
# 1. Kräfte:
# Die Kraft im Hooke-Element (Feder mit der Federsteifigkeit k) ist
> FH:=unapply(simplify(k*Deltal(t)),t);
# Die Kraft im Maxwell-Element ist
> FM(t);
# Die Kraft im Gesamtmodell ist 
> FG:=unapply(FH(t)+FM(t),t);
# 2. Längenänderungen
# Wir beginnen die Zeitzählung bei 
> t0:=0;
# Längenänderung des Dämpfers im Maxwell-Element (t0  = 0)
> Deltal_D1(t);
# Die Längenänderung der Feder im Maxwell-Element ist 
> Deltal_F1(t);
> eval(Deltal(t));
> 2/3+48*4/(9*97);
# Wir stellen die Zustandsgrößen grafisch dar. 
> tE:=15.:
> p1:=plot([F(t),FH(t),FM(t)],t=0..tE,title = "\nKräfte im Standard-Modell\n", legend = ["F", "FH","FM"], titlefont = ["ARIAL", 15], linestyle = [solid, solid, solid], axesfont = ["HELVETICA", "ROMAN", 8],legendstyle = [font = ["HELVETICA", 9], location = bottom],axes=boxed,color=[black,red,blue],gridlines):
> p2:=plot([Deltal(t),Deltal_F1(t),Deltal_D1(t)],t=0..tE,title = "\nLängenänderungen im Standard-Modell\n", legend = ["Gesamt", "Feder1","Dämpfer"], titlefont = ["ARIAL", 15], linestyle = [solid, solid, solid], axesfont = ["HELVETICA", "ROMAN", 8], legendstyle = [font = ["HELVETICA", 9], location = bottom],axes=boxed,color=[black,red,blue],gridlines):
> AA:=Array(1..2): AA[1]:=p1: AA[2]:=p2: 
> plots[display](AA);
# In der folgenden Grafik werden die Kräfte über der Verschiebung des Gesamtmodells aufgetragen 
> tae:=t=0..2.*Pi/Omega;
> plot([[Deltal(t),F(t),tae],[Deltal(t),FH(t),tae],[Deltal(t),FM(t),tae]],scaling=constrained,title = "\nKraft-Verschiebungskurven im Standard-Modell\n",titlefont = ["ARIAL", 15], legend = ["F", "FH","FM"],legendstyle = [font = ["HELVETICA", 9], location = bottom],axes=boxed,scaling = constrained, color=[black, red, blue],labels = ["Verschiebung Gesamtmodell","Kräfte"],gridlines=true);
# Hinweis: Nach hinreichend großer Zeit verschwindet die Anfangsstörung  in den Lösungen und die anfangs offenen Ellipsen sind dann näherungsweise geschlossen:
> tae:=t=10*Pi/Omega..12*Pi/Omega;
> plot([[Deltal(t),F(t),tae],[Deltal(t),FH(t),tae],[Deltal(t),FM(t),tae]],scaling=constrained,title = "\nKraft-Verschiebungskurven im Standard-Modell\n",titlefont = ["ARIAL", 15], legend = ["F", "FH","FM"],legendstyle = [font = ["HELVETICA", 9], location = bottom],axes=boxed,scaling = constrained, color=[black, red, blue],labels = ["Verschiebung Gesamtmodell","Kräfte"],gridlines=true);
> 
;
